Le premier site francophone dédié au développement Pocket PC

Comment utiliser POOM avec eVB ? Partie 2 : Les Tâches

Voir la première partie

Cet article va vous expliquer comment accéder aux tâches que vous avez définies dans votre Pocket PC.

Comme cet article fait référence à des opérations expliquées dans l'article précédent, nous vous conseillons vivement de consulter la première partie avant de continuer.

Nous partons du principe que nous disposons d'un objet de type PocketOutlook.Application (notre variable wPOOM), et que nous avons exécuté avec succès la méthode "Logon" de cet objet.

Accéder aux tâches

POOM stocke ses données dans des dossiers (folders). Il faut donc se 'brancher' sur le dossier des tâches pour pouvoir les manipuler :

Dim wTaskFolder as PocketOutlook.Folder
Set wTaskFolder = wPOOM.GetDefaultFolder(olFolderTasks)

wTaskFolder pointe maintenant sur le dossier PocketOutlook des tâches. Toutes les tâches que vous avez définies sont listées dans une collection de cet objet, la collection "Items" (de type "PocketOutlook.Items") qui contient des objets de type "PocketOutlook.TaskItem" :

Dim wTasks as PocketOutlook.Items
Dim wTask as PocketOutlook.TaskItem

Set wTasks = wTaskFolder.Items
For Each wTask In wTasks
Call wTask.Display
Next

Si vous exécutez ce code, PocketOutlook va afficher une fiche tâche pour chaque tâche présente dans la collection wTasks !

Important : Chaque fiche est affichée de manière modale, ce qui arrête votre code eVB tand que vous ne fermez pas la tâche avec le bouton OK.

Attention : La méthode "Display" de l'objet "TaskItem" affiche les informations concernant la tâche, mais aussi vous permet de modifier ces informations, donc attention.

Créer une nouveller tâche

Pour créer une nouvelle tâche, il faut renseigner les propriétés d'un objet de type "TaskItem" :

Dim wTask as PocketOutlook.TaskItem

Rem Création d'une nouvelle tâche (code 3)
Set wTask = wPOOM.CreateItem(3)

Rem On remplit les infos de base, le sujet, une note
Rem la date d'échéance
Rem et la date de démarrage
wTask.Subject = "Ma nouvelle tâche"
wTask.Body="Blablablablabla"
wTask.DueDate = cDate("15/08/2001")
wTask.StartDate = Now

Rem On indique qu'il faut exécuter un rappel (vrai par défaut)
Rem avec un message et un son dès la veille de l'échéance
wTask.ReminderSet = True
Rem L'option 8 or 1 indique que l'on veut un son (8)
Rem plus (or) un message (1)
wTask.ReminderOptions = 8 or 1
wTask.ReminderSoundFile = "Alarm1"
wTask.ReminderTime = cDate("14/08/2001")

Rem On enregistre cette nouvelle Tâche
Call wTask.Save

Trouver des Tâches par rapport à des critères

Si vous voulez récupérer uniquement les tâches par rapport à des criètes, vous devez utiliser la méthode "Restrict" de la collection des tâches (Items) et donner sous forme de chaine le ou les filtres. Ces filtres sont en fait les nom des propriétés avec des crochets, et les valeurs sont toujours des chaines (il faut donc ajouter les guillemets avec Chr(34)). Par exemple, si l'on veut créer un filtre sur la date d'échéance égale à 15/08/2001 il faudra écrire : [DueDate] = "15/08/2001"

Dim wTaskFolder as PocketOutlook.Folder
Dim wTasks as PocketOutlook.Items
Dim wTask as PocketOutlook.TaskItem

Rem On récupère le dossier des Tâches
Set wTaskFolder = wPOOM.GetDefaultFolder(olFolderTasks)
Rem On récupère la collection des tâches dont la date d'échéance est = à 15/08/2001
Set wTasks = wTaskFolder.Items.Restrict("[DueDate] = " & Chr(34) & "15/08/2001" & Chr(34))
For Each wTask in wTasks
Call wTask.Display
Next

Si vous voulez toutes les tâches qui commencent le 15/07/2002, il faut écrire : [StartDate] = "15/07/2002"

Détruire une tâche

Pour détruire une tâche, il faut utiliser la méthode "Delete" de l'objet "TaskItem" qui contient la tâche que vous voulez détruire :

Dim wTaskFolder as PocketOutlook.Folder
Dim wTasks as PocketOutlook.Items
Dim wTask as PocketOutlook.TaskItem

Rem On récupère le dossier des Tâches
Set wTaskFolder = wPOOM.GetDefaultFolder(olFolderTasks)
Rem On récupère la collection des tâches
Set wTasks = wTaskFolder.Items
Rem Et on détruit la première de la collection
Call wTasks(1).Delete

Voilà, vous savez globalement comment gérer les tâches avec POOM. Biensûr, il existe certaines méthodes et propriétés dont nous avons délibérément omis de parler car elles ne rentre pas dans le cadre de cet article d'initiation. Si vous avez des problèmes avec les tâches n'oubliez pas que le forum eVB d' est là pour vous aider.

La troisième partie va vous expliquer comment gérer les contacts avec POOM.

Stéphane Sibué