Le premier site francophone dédié au développement Pocket PC

Comment changer l'ordre des colonnes d'un Listview au stylet ?

Il existe un moyen de permettre à l'utilisateur de choisir l'ordre des colonnes de votre ListView (en mode report biensûr). Cette propriété est très pratique et permet un niveau encore plus grand de paramétrage de votre application. Comme pour l'activation du mode 'GridLine', 'FullRowSelect' ou encore le calcul automatique de la largeur des colonnes, il faut envoyer un message au ListView pour lui indiquer qu'il doit autoriser le changement de l'ordre des colonnes au stylet.

Envoyer un message au ListView

Note: La technique que nous utilisons ici est celle que nous avons déjà utilisé pour rendre notre ListView FullRowSelect et lui ajouter une grille et pour calculer automatiquement la largeur des colonnes.

Pour envoyer un message il faut utiliser la fonction "SendMessage" qui est incluse dans la librairie dynamique Coredll (comme souvent). Cette API est déclarée en eVB de la manière suivante :

Declare Function SendMessage Lib "Coredll" Alias "SendMessageW" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Pour envoyer un message à un contrôle, il faut donner en paramètre de la fonction "SendMessage" le handle du contrôle (le hWnd), ce qui nous pose un gros problème car le contrôle ListView de eVB ne nous fournit pas cette information. Pour contourner ce problème, nous allons récupérer le hWnd de notre ListView grace à la fonction "GetFocus" (encore une API de Coredll) qui retourne le hWnd de l'objet qui a le focus au moment de l'appel. Ce système fonctionne très bien mais il faut impérativement que le contrôle ListView soit visible et qu'il ait le focus. La fonction "GetFocus" se déclare en eVB de la manière suivante :

Public Declare Function GetFocus Lib "Coredll" () As Long

Modifier le style du ListView

Pour indiquer au ListView que l'on autorise la modification de l'ordre des colonnes, il faut tout d'abord récupérer les paramètres de style, puis appliquer le paramètre LVS_EX_HEADERDRAGDROP, puis remplacer les anciens paramètres par les nouveaux (3 étapes donc). Pour effectuer cette opération nous avons aussi besoin de constantes :

Const LVM_GETEXTENDEDLISTVIEWSTYLE = &H1037
Const LVM_SETEXTENDEDLISTVIEWSTYLE = &H1036
Const LVS_EX_HEADERDRAGDROP = &H10

Nous pouvons écrire notre fonction qui va modifier le style de notre ListView et activer la sélection sur toute la ligne :

Sub LVFullRowSelect(ByVal wLV As ListViewCtrl)

Dim h As Long
Dim s As Long

Rem On récupère le hWnd du ListView en lui donnant le focus et en
Rem Utilisant l'API GetFocus()
Call wLV.SetFocus
h = GetFocus()

Rem On récupère les paramètres de style courant du ListView dans s
s = SendMessage(h, LVM_GETEXTENDEDLISTVIEWSTYLE, 0, 0)

Rem On ajoute (si celà n'est pas déjà le cas) l'autorisation de changement
Rem de l'ordre des colonnes au stylet
s = s Or LVS_EX_HEADERDRAGDROP

Rem On enregistre les nouveaux paramètres
Call SendMessage(h, LVM_SETEXTENDEDLISTVIEWSTYLE, 0, s)

End Sub

Voila, votre programme eVB ressemble de plus en plus à un programme écrit en C++

Stéphane Sibué